Парсинг menu_additem из файла [Решено]

[deadkid56]

Здравствуйте, интересует как создать динамическое меню, считывающая из файла в таком формате:
"Название пункта в меню" "команда, выполняющаяся при выборе пункта". Если кто-то поможет, буду очень рад

[NoPM_N1Ck]

Погугли

[RevCrew]

Код: Выделить всё

#include <amxmodx>

new PLUGIN[]  = "";
new AUTHOR[]  = "";
new VERSION[] = "0.00";

#define FILE "addons/amxmodx/data/menu.txt"

enum menuArray {
    Name[64],
    Cmd[64]
}

new Array: g_array_file;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_array_file = ArrayCreate(menuArray);
    
    parse_file(FILE);
}

public showMenu(id) {
    
    new data[menuArray];
    new size = ArraySize(g_array_file);
    
    new menu = menu_create("Menu title", "MenuHandler");
    for(new i; i<size; i++) {
        ArrayGetArray(g_array_file, i, data);
        menu_additem(menu, data[Name], data[Cmd]);
    }
    
    menu_display(id, menu, 0);
}

public MenuHandler(id, menu, item)
{
    
    if (item == MENU_EXIT)
        return menu_destroy(menu);
    
    new s_Data[64], s_Name[64], i_Access, i_Callback
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback);
    
    new name[32];
    get_user_name(id, name, 31);
    log_amx("Client %s, item %s, command %s", name, s_Name, s_Data);
    
    client_cmd(id, s_Data);
    return menu_destroy(menu);
}

stock parse_file ( file[] )
{
    new f = fopen( file, "r");
    
    if ( !f)    return;
    
    new filedata[128], data[menuArray];
    
    while (!feof(f)) {
        fgets(f, filedata, charsmax(filedata));
        
        if(!filedata[0] || filedata[0] != '"')
            continue;
            
        parse(filedata, data[Name], 63, data[Cmd], 63);
        
        ArrayPushArray(g_array_file, data);
    }
    
    fclose(f);
}

[deadkid56]

Код: Выделить всё

#include <amxmodx>

new PLUGIN[]  = "";
new AUTHOR[]  = "";
new VERSION[] = "0.00";

#define FILE "addons/amxmodx/data/menu.txt"

enum menuArray {
    Name[64],
    Cmd[64]
}

new Array: g_array_file;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_array_file = ArrayCreate(menuArray);
    
    parse_file(FILE);
}

public showMenu(id) {
    
    new data[menuArray];
    new size = ArraySize(g_array_file);
    
    new menu = menu_create("Menu title", "MenuHandler");
    for(new i; i<size; i++) {
        ArrayGetArray(g_array_file, i, data);
        menu_additem(menu, data[Name], data[Cmd]);
    }
    
    menu_display(id, menu, 0);
}

public MenuHandler(id, menu, item)
{
    
    if (item == MENU_EXIT)
        return menu_destroy(menu);
    
    new s_Data[64], s_Name[64], i_Access, i_Callback
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback);
    
    new name[32];
    get_user_name(id, name, 31);
    log_amx("Client %s, item %s, command %s", name, s_Name, s_Data);
    
    return client_cmd(id, s_Data);
}

stock parse_file ( file[] )
{
    new f = fopen( file, "r");
    
    if ( !f)    return;
    
    new filedata[128], data[menuArray];
    
    while (!feof(f)) {
        fgets(f, filedata, charsmax(filedata));
        
        if(!filedata[0] || filedata[0] != '"')
            continue;
            
        parse(filedata, data[Name], 63, data[Cmd], 63);
        
        ArrayPushArray(g_array_file, data);
    }
    
    fclose(f);
}

Спасибо!!
Я вам очень благодарен

[Mistrick]

RevCrew, а после обычного выбора меню удалять уже не надо?

[RevCrew]

Спасибо, исправил