Русское сообщество по скриптингу

Новая система меню AMXX

Статьи или фрагменты кода для новичков и уже опытных скриптеров по AMXX.

Модератор: Chuvi

Правила форума
1. Запрещено материться и оскорблять других участников форума.
2. Запрещен флуд, оффтоп, дабл постинг во всех разделах форума, кроме раздела "Болтовня".
3. Запрещено взламывать сайт/форум или наносить любой вред проекту.
4. Запрещено рекламировать другие ресурсы.
5. Запрещено создавать темы без информативного названия. Название темы должно отображать ее смысл.

В данном разделе форума разрешено создавать темы, касающие только обучающему материалу по AMX Mod X.

Новая система меню AMXX

Сообщение DJ_WEST » 28 окт 2009, 15:15

Автор: Emp`
Перевод и редактирование: DJ_WEST

В данной статье рассказывается и показываются примеры по созданию нового игрового меню через AMX Mod X.
  • Если вы создается меню, опции которого не изменяются (постоянные), то лучше всего создать его, как глобальное. Не нужно его уничтожать и заново создавать по несколько раз.
  • Если небходимо выровнять текст в меню по правому краю, то используйте \R.
  • Меню не будет показываться, если у него нет опций.
  • Для того чтобы убрать отображение меню у игрока на экране, можно использовать код:
    Код: Выделить всё
    show_menu(id, 0, "^n", 1) 
  • Список цветов, которые можно использовать при создании меню:
    • Белый - \w
    • Желтый - \y
    • Красный - \r
    • Серый - \d

Функции:
  • Создание меню
    Код: Выделить всё
    menu_create(title[], handler[], ml=0) 

    title - заголовок меню, который отображается сверху.
    handler - функция, с которой будет происходить взаимодействие, когда произошло нажатие одной из опций.
    ml - использовать мультиязычность при формировании меню.
  • Добавление опции меню
    Код: Выделить всё
    menu_additem(menu, const name[], const command[], paccess=0, callback=-1) 

    menu - меню, с которым мы будем взаимодействовать.
    name - название опции меню (нумерация происходит автоматически).
    command - информация, которую мы посылаем при использовании данной опции.
    paccess - уровень доступа к данной опции (флаг администратора).
    callback- если данная опция установлена (это должен быть результат функции menu_makecallback), то будет вызов функции до вывода опции на экран, что даст возможность изменить опцию в реальном времени.
  • Установка свойств меню
    Код: Выделить всё
    menu_setprop(menu, prop, ...) 

    menu - меню, с которым мы будем взаимодействовать.
    prop - свойство меню.
  • Отображение меню
    Код: Выделить всё
    menu_display(id, menu, page) 

    id - индекс игрока, которому мы должны показать меню.
    menu - меню, которое необходимо показать.
    page - страница меню, с которой начинается отображение.
  • Уничтожение меню
    Код: Выделить всё
    menu_destroy(menu) 

    menu - меню, которое нужно уничтожить. После вызова данной функции необходимо использовать return PLUGIN_HANDLED.
  • Получение информации об опции меню
    Код: Выделить всё
    menu_item_getinfo(menu, item, &access, command[], cmdlen, name[]="", namelen=0, &callback)
     

    menu - меню, из которого необходимо получить информацию.
    item - опция, о которой необходимо получить информацию.
    access - уровень доступа для указанной опции.
    command - данные, передаваемые данной опцией.
    cmdlen - длина данных.
    name - название опции меню.
    namelen - длина названия.
    callback - значение callback.
  • Добавление пустой опции (пробел)
    Код: Выделить всё
    menu_addblank(menu, slot=1) 

    menu - меню, с которым необходимо произвести действие.
    slot - если значение больше 0, то увеличивает пробелы в данном количестве раз.
    Можно использовать только после menu_additem.
  • Отменить меню у игрока
    Код: Выделить всё
    menu_cancel(player) 

    player - игрок, у которого необходимо отменить действие меню, меню останется на экране игрока, но любое действие будет анулировано.
  • Количество опций в меню
    Код: Выделить всё
    menu_items(menu) 

    menu - меню, у которого необходимо получить кол-во опций.
  • Количество страниц в меню
    Код: Выделить всё
    menu_pages(menu) 

    menu - меню, у которого необходимо получить кол-во страниц.
  • Установить callback на опцию меню
    Код: Выделить всё
    menu_item_setcall(menu, item, callback=-1) 

    menu - меню, с которым происходит взаимодействие.
    item - опция меню.
    callback - значение для callback.
  • Установить команду на опцию меню
    Код: Выделить всё
    menu_item_setcmd(menu, item, cmd[]) 

    menu - меню, с которым происходит взаимодействие.
    item - опция меню.
    cmd - команда опции.
  • Установить название опции меню
    Код: Выделить всё
    menu_item_setname(menu, item, name[]) 

    menu - меню, с которым происходит взаимодействие.
    item - опция меню.
    name - название опции.
  • Создание callback функции
    Код: Выделить всё
    menu_makecallback(function[]) 

    function - название функции для callback.
    Данная функция передает аргументы id игрока, id меню и id опции:
    Код: Выделить всё
    public function(id, menu, item) 

    Функция может возвращать следующие значения: ITEM_IGNORE, ITEM_ENABLED или ITEM_DISABLED.

Создание базисного меню (основной пример)
Код: Выделить всё
#include <amxmodx>

public plugin_init()
{
    // Данные вашего плагина

    // Клиентская команда для вызова меню
    register_clcmd("my_menu", "My_Menu")
}

// Создадим функцию, которая будет формировать меню
public My_Menu(id)
{
    // Сперва необходимо создать переменную для меню, с которой мы будем взаимодействовать в дальнейшем
    new i_Menu = menu_create("\rTitle of my menu:", "menu_handler")

    // Теперь добавим некоторые опции для меню
    menu_additem(i_Menu, "\wFirst option #1", "1", 0)
    menu_additem(i_Menu, "\wSecond option #2", "2", 0)
    menu_additem(i_Menu, "\wAdmin option #3", "3", ADMIN_ADMIN)

    // Устанавливаем свойства меню
    menu_setprop(i_Menu, MPROP_EXIT, MEXIT_ALL)

    // Отображение меню игроку
    menu_display(id, i_Menu, 0)
 }

// Создадим теперь функцию обработки действий меню
public menu_handler(id, menu, item)
{
    // Если игрок нажал выход из меню
    if (item == MENU_EXIT)
    {
        // Уничтожение меню
        menu_destroy(menu)
        
        return PLUGIN_HANDLED
    
}

    // Теперь создадим переменные, необходимые для получения информации о меню и нажатой опции
    new s_Data[6], s_Name[64], i_Access, i_Callback

    
// Получаем информацию об опции
    menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

    // Если посмотреть раньше на использовании menu_additem, то можно увидеть, что мы посылали некоторую информацию
    // В данном случае вся информация - целочисленная
    new i_Key = str_to_num(s_Data)

    // Теперь найдем, какая именно опция была использована
    switch(i_Key)
    {
        case 1:
        {
            client_print(id, print_chat, "You selected first option")
            // Уничтожение меню
            menu_destroy(menu)
            return PLUGIN_HANDLED
        
}
        case 2:
        {
            client_print(id, print_chat, "You selected second option")
        }
        case 3:
        {
            client_print(id, print_chat, "You selected admin option")
        }
    }

    // Уничтожение меню
    menu_destroy(menu)
    return PLUGIN_HANDLED
 
}
 


Создание меню, сформированного из игроков на сервере
Код: Выделить всё
#include <amxmodx>
#include <fun>

public plugin_init()
{
    // Клиентская команда для вызова меню
    register_clcmd("my_menu", "My_Menu")
}

public My_Menu(id)
{
    // Сперва необходимо создать переменную для меню, с которой мы будем взаимодействовать в дальнейшем
    new i_Menu = menu_create("\rPlayer menu:", "menu_handler")

    // Необходимые переменные, которые понадобятся нам при выводе меню из игроков
    new s_Players[32], i_Num, i_Player

    
// Переменные для хранения информации об игроках
    new s_Name[32], s_Player[10]

    // Получаем массив игроков
    get_players(s_Players, i_Num)

    // Цикл по всем игрокам
    for (new i; i < i_Num; i++)
    { 
        
// Сохраняем текущего игрока в i_Player
        i_Player = s_Players[i]

        // Получаем имя и ID игрока
        get_user_name(i_Player, s_Name, charsmax(s_Name))
        num_to_str(i_Player, s_Player, charsmax(s_Player))

        // Добавляем опцию по данному игроку
        menu_additem(i_Menu, s_Name, s_Player, 0)

    }

    // Мы сформировали меню из игроков, присутствующих на сервере, теперь выводим его
    menu_display(id, i_Menu, 0)
}
 
public menu_handler
(id, menu, item)
{
    if (item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    
}

    new s_Data[6], s_Name[64], i_Access, i_Callback
    menu_item_getinfo
(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

    // Получаем ID игрока, который был выбран в меню
    new i_Player = str_to_num(s_Data)

    // Проверяем, если игрок живой
    if (is_user_alive(i_Player))
        // Устанавливаем его здоровье в 100 HP
        set_user_health(i_Player, 100)

    menu_destroy(menu)
    return PLUGIN_HANDLED
 
} 


Создание меню для голосования
Код: Выделить всё
#include <amxmodx>

// Для хранения меню голсоований
new g_VoteMenu
// Для хранения голосов за каждую опцию
new g_Votes[2]
// Для проверки, если голосование уже запущено
new g_Voting

public plugin_init
()
{
    register_clcmd("start_vote", "StartVote")
}
 
public StartVote
(id)
{
    // Если голосование уже запущено, то выходим
    if (g_Voting)
    {
        client_print(id, print_chat, "There is already a vote going.")
        // Мы возвращаем PLUGIN_HANDLED, чтобы в консоли игрока не было сообщения unknown command
        return PLUGIN_HANDLED
    
}

    g_VoteMenu = menu_create("\rVote Menu:", "menu_handler")

    menu_additem(g_VoteMenu, "Vote Option 1", "0", 0)
    menu_additem(g_VoteMenu, "Vote Option 2", "1", 0)
    
    new s_Players
[32], i_Num, i_Player
    get_players
(s_Players, i_Num)

    for (new i; i < i_Num; i++)
    {
        i_Player = s_Players[i]

        menu_display(i_Player, g_VoteMenu, 0)

        // Увеличиваем, чтобы узнать сколько игроков голосуют
        g_Voting++
    }

    // Останавливаем голосование через 10 секунд
    set_task(10.0, "EndVote")

    return PLUGIN_HANDLED
}
 
public menu_handler
(id, menu, item)
{
    if (item == MENU_EXIT)
        return PLUGIN_HANDLED

    new s_Data
[6], s_Name[64], i_Access, i_Callback
    menu_item_getinfo
(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

    // Полчаем информацию о том, какая опция была выбрана
    new i_Vote = str_to_num(s_Data)

    // Увеличиваем количество голосов по данной опции
    g_Votes[i_Vote]++

    return PLUGIN_HANDLED
}
 
public EndVote
()
{
     // Если первая опция набрала больше голосов, чем вторая
    if (g_Votes[0] > g_Votes[1])
        client_print(0, print_chat, "First option recieved most votes (%d)", g_Votes[0])
    // Иначе если вторая опция набрала больше голосов, чем первая
    else if (g_Votes[1] > g_Votes[0])
        client_print(0, print_chat, "Second option recieved most votes (%d)", g_Votes[1])
    // Иначе равное кол-во голосов
    else
        client_print
(0, print_chat, "The vote tied at %d votes each.", g_Votes[0])

    menu_destroy(g_VoteMenu)

    // Сбрасываем информацию о том, что игроки голосуют
    g_Voting = 0
} 


Создание меню с использованием под-меню
Код: Выделить всё
#include <amxmodx>

public plugin_init()
{
    register_clcmd( "my_menu","My_Menu")
}

public My_Menu(id)
{
    new i_Menu = menu_create("\rMy menu:", "menu_handler")

    menu_additem(i_Menu, "\wFirst option #1", "1", 0)
    menu_additem(i_Menu, "\wSub-Menu #2", "2", 0)

    menu_setprop(i_Menu, MPROP_EXIT, MEXIT_ALL)
    menu_display(id, i_Menu, 0)
}

public menu_handler(id, menu, item)
{
    if (item == MENU_EXIT)
    {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    
}

    new s_Data[6], s_Name[64], i_Access, i_Callback
    menu_item_getinfo
(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)
    
    new i_Key 
= str_to_num(s_Data)

    switch(i_Key)
    {
        case 1:
        {
            client_print(id, print_chat, "You selected first option")
        }
        case 2:
        {
            // Открыть под-меню
            Sub_Menu(id)
        }
    }

    menu_destroy(menu)
    return PLUGIN_HANDLED
}

public Sub_Menu(id)
{
    // Создаем новое меню, но функция обработки действий будет другая
    new i_Menu = menu_create("\rSub-Menu:", "submenu_handler")

    menu_additem(i_Menu, "\wSub-option #1", "1", 0)
    menu_additem(i_Menu, "\wSub-option #2", "2", 0)

    menu_setprop(i_Menu, MPROP_EXIT, MEXIT_ALL)
    menu_display(id, i_Menu, 0)
}

public submenu_handler(id, menu, item)
{
    if (item == MENU_EXIT)
    {
        menu_destroy(menu)

        // Если игрок на сервере, то показываем главное меню
        if (is_user_connected(id))
            My_Menu(id)

        return PLUGIN_HANDLED
    
}

    new s_Data[6], s_Name[64], i_Access, i_Callback
    menu_item_getinfo
(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

    new i_Key = str_to_num(s_Data)

    switch(i_Key)
    {
        case 1:
        {
            client_print(id, print_chat, "You selected first sub-option")
        }
        case 2:
        {
            client_print(id, print_chat, "You selected second sub-option")
        }
    }

    menu_destroy(menu)

    // Если вы хотите показать главное меню потом
    My_Menu(id)

    return PLUGIN_HANDLED
} 
Не пишите мне в ЛС: если вам нужна помощь на бесплатной основе. Любые вопросы на форум.
Аватара пользователя
DJ_WEST
Администратор
 
Сообщения: 3649
Зарегистрирован: 22 авг 2009, 00:38
Благодарил (а): 48 раз.
Поблагодарили: 2177 раз.
Опыт программирования: Больше трех лет
Языки программирования: Counter-Strike 1.6
Counter-Strike: Source
Left 4 Dead
Left 4 Dead 2

Re: Новая система меню AMXX

Сообщение okeeey » 28 мар 2014, 01:28

Как в меню, сформированного из игроков на сервере, сделать на 7 пункт время бана, как например у amxbans. Подробнее, если можно. :dntknw:
Аватара пользователя
okeeey
 
Сообщения: 26
Зарегистрирован: 26 мар 2014, 23:42
Благодарил (а): 5 раз.
Поблагодарили: 2 раз.
Опыт программирования: Больше трех лет
Языки программирования: Counter-Strike 1.6

Re: Новая система меню AMXX

Сообщение ttodonok » 06 сен 2014, 14:21

Всем привет я новечок может кто помочь разобратся с таким меню
ну вот пример!
Заходим на ДМ а там вам предлогается взять следующие Вы должны зарегистрироваться, чтобы видеть ссылки.
Нажали 1 и выскакивает Вы должны зарегистрироваться, чтобы видеть ссылки.

Тоесть у меня на серваке стоят мои оружия что бы они были прописаны в это меню может кто нить хотя бы ссылку дать на видео урок по созданию такого меню
Мои оружия можно взять командой в чат say/post (дают пистоле) say/ggg (дают дробовик)
Аватара пользователя
ttodonok
 
Сообщения: 4
Зарегистрирован: 06 сен 2014, 14:17
Благодарил (а): 0 раз.
Поблагодарили: 0 раз.
Опыт программирования: Около 6 месяцев
Языки программирования: Counter-Strike 1.6

Re: Новая система меню AMXX

Сообщение Subb98 » 06 сен 2014, 14:26

ttodonok писал(а):может кто нить хотя бы ссылку дать на видео урок по созданию такого меню


«Очень хорошо. Лучше вы, чем я» © Donald J. Trump
Аватара пользователя
Subb98
Модератор
 
Сообщения: 4825
Зарегистрирован: 24 мар 2011, 19:42
Откуда: г. Пермь
Благодарил (а): 1272 раз.
Поблагодарили: 2184 раз.
Опыт программирования: Больше трех лет
Языки программирования: Pawn, PHP

Re: Новая система меню AMXX

Сообщение D34by » 06 сен 2014, 14:32

Subb98 писал(а):
ttodonok писал(а):может кто нить хотя бы ссылку дать на видео урок по созданию такого меню



Уже не нажимая кнопку play, я понял что там будет, точнее кто :-D
Work with Zombie Plague ver. 4|5, Biohazard, Zombie Engine, Public, Weapon System
Аватара пользователя
D34by
 
Сообщения: 538
Зарегистрирован: 13 фев 2014, 12:45
Благодарил (а): 15 раз.
Поблагодарили: 191 раз.
Опыт программирования: Больше трех лет
Языки программирования: пешка
сишка

Re: Новая система меню AMXX

Сообщение ttodonok » 06 сен 2014, 14:54

ребят если может кто помочь реально помогите, код ибо скайпа освьте добавлю пообщаемся возмодно оплата за помощь
Аватара пользователя
ttodonok
 
Сообщения: 4
Зарегистрирован: 06 сен 2014, 14:17
Благодарил (а): 0 раз.
Поблагодарили: 0 раз.
Опыт программирования: Около 6 месяцев
Языки программирования: Counter-Strike 1.6

Re: Новая система меню AMXX

Сообщение Subb98 » 06 сен 2014, 15:25

ttodonok, напишите Radius'у или Safety1st'у - они занимаются обучением на платной основе.
«Очень хорошо. Лучше вы, чем я» © Donald J. Trump
Аватара пользователя
Subb98
Модератор
 
Сообщения: 4825
Зарегистрирован: 24 мар 2011, 19:42
Откуда: г. Пермь
Благодарил (а): 1272 раз.
Поблагодарили: 2184 раз.
Опыт программирования: Больше трех лет
Языки программирования: Pawn, PHP

Re: Новая система меню AMXX

Сообщение Dmitry Beast » 06 сен 2014, 15:40

[pawn]
  1. #include <amxmodx>

  2.  

  3. // Для хранения меню голсоований

  4. new g_VoteMenu

  5. // Для хранения голосов за каждую опцию

  6. new g_Votes[2]

  7. // Для проверки, если голосование уже запущено

  8. new g_Voting

  9.  

  10. public plugin_init()

  11. {

  12.     register_clcmd("start_vote", "StartVote")

  13. }

  14.  

  15. public StartVote(id)

  16. {

  17.     // Если голосование уже запущено, то выходим

  18.     if (g_Voting)

  19.     {

  20.         client_print(id, print_chat, "There is already a vote going.")

  21.         // Мы возвращаем PLUGIN_HANDLED, чтобы в консоли игрока не было сообщения unknown command

  22.         return PLUGIN_HANDLED

  23.     }

  24.  

  25.     g_VoteMenu = menu_create("\rVote Menu:", "menu_handler")

  26.  

  27.     menu_additem(g_VoteMenu, "Vote Option 1", "0", 0)

  28.     menu_additem(g_VoteMenu, "Vote Option 2", "1", 0)

  29.    

  30.     new s_Players[32], i_Num, i_Player

  31.     get_players(s_Players, i_Num)

  32.  

  33.     for (new i; i < i_Num; i++)

  34.     {

  35.         i_Player = s_Players[i]

  36.  

  37.         menu_display(i_Player, g_VoteMenu, 0)

  38.  

  39.         // Увеличиваем, чтобы узнать сколько игроков голосуют

  40.         g_Voting++

  41.     }

  42.  

  43.     // Останавливаем голосование через 10 секунд

  44.     set_task(10.0, "EndVote")

  45.  

  46.     return PLUGIN_HANDLED

  47. }

  48.  

  49. public menu_handler(id, menu, item)

  50. {

  51.     if (item == MENU_EXIT)

  52.         return PLUGIN_HANDLED

  53.  

  54.     new s_Data[6], s_Name[64], i_Access, i_Callback

  55.     menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

  56.  

  57.     // Полчаем информацию о том, какая опция была выбрана

  58.     new i_Vote = str_to_num(s_Data)

  59.  

  60.     // Увеличиваем количество голосов по данной опции

  61.     g_Votes[i_Vote]++

  62.  

  63.     new szName[32];

  64.     get_user_name(id, szName, charsmax(szName));

  65.     client_print(0, print_chat, "%s выбрал пункт %d", szName, item);

  66.  

  67.     return PLUGIN_HANDLED

  68. }

  69.  

  70. public EndVote()

  71. {

  72.      // Если первая опция набрала больше голосов, чем вторая

  73.     if (g_Votes[0] > g_Votes[1])

  74.         client_print(0, print_chat, "First option recieved most votes (%d)", g_Votes[0])

  75.     // Иначе если вторая опция набрала больше голосов, чем первая

  76.     else if (g_Votes[1] > g_Votes[0])

  77.         client_print(0, print_chat, "Second option recieved most votes (%d)", g_Votes[1])

  78.     // Иначе равное кол-во голосов

  79.     else

  80.         client_print(0, print_chat, "The vote tied at %d votes each.", g_Votes[0])

  81.  

  82.     menu_destroy(g_VoteMenu)

  83.  

  84.     // Сбрасываем информацию о том, что игроки голосуют

  85.     g_Voting = 0

  86. }
[/pawn]

Будет показывать кто что выбрал, спасибо subb98 :thumbs_up
Аватара пользователя
Dmitry Beast
 
Сообщения: 1533
Зарегистрирован: 24 дек 2010, 10:35
Откуда: Челябинск
Благодарил (а): 431 раз.
Поблагодарили: 206 раз.
Опыт программирования: Больше трех лет
Языки программирования: All Languages

Re: Новая система меню AMXX

Сообщение ttodonok » 06 сен 2014, 15:46

Subb98 писал(а):ttodonok, напишите Radius'у или Safety1st'у - они занимаются обучением на платной основе.

А как мне им написать может есть скайп лил ссылка на их инфу?

Добавлено спустя 34 секунды:
BeasT писал(а):[pawn]
  1. #include <amxmodx>

  2.  

  3. // Для хранения меню голсоований

  4. new g_VoteMenu

  5. // Для хранения голосов за каждую опцию

  6. new g_Votes[2]

  7. // Для проверки, если голосование уже запущено

  8. new g_Voting

  9.  

  10. public plugin_init()

  11. {

  12.     register_clcmd("start_vote", "StartVote")

  13. }

  14.  

  15. public StartVote(id)

  16. {

  17.     // Если голосование уже запущено, то выходим

  18.     if (g_Voting)

  19.     {

  20.         client_print(id, print_chat, "There is already a vote going.")

  21.         // Мы возвращаем PLUGIN_HANDLED, чтобы в консоли игрока не было сообщения unknown command

  22.         return PLUGIN_HANDLED

  23.     }

  24.  

  25.     g_VoteMenu = menu_create("\rVote Menu:", "menu_handler")

  26.  

  27.     menu_additem(g_VoteMenu, "Vote Option 1", "0", 0)

  28.     menu_additem(g_VoteMenu, "Vote Option 2", "1", 0)

  29.    

  30.     new s_Players[32], i_Num, i_Player

  31.     get_players(s_Players, i_Num)

  32.  

  33.     for (new i; i < i_Num; i++)

  34.     {

  35.         i_Player = s_Players[i]

  36.  

  37.         menu_display(i_Player, g_VoteMenu, 0)

  38.  

  39.         // Увеличиваем, чтобы узнать сколько игроков голосуют

  40.         g_Voting++

  41.     }

  42.  

  43.     // Останавливаем голосование через 10 секунд

  44.     set_task(10.0, "EndVote")

  45.  

  46.     return PLUGIN_HANDLED

  47. }

  48.  

  49. public menu_handler(id, menu, item)

  50. {

  51.     if (item == MENU_EXIT)

  52.         return PLUGIN_HANDLED

  53.  

  54.     new s_Data[6], s_Name[64], i_Access, i_Callback

  55.     menu_item_getinfo(menu, item, i_Access, s_Data, charsmax(s_Data), s_Name, charsmax(s_Name), i_Callback)

  56.  

  57.     // Полчаем информацию о том, какая опция была выбрана

  58.     new i_Vote = str_to_num(s_Data)

  59.  

  60.     // Увеличиваем количество голосов по данной опции

  61.     g_Votes[i_Vote]++

  62.  

  63.     new szName[32];

  64.     get_user_name(id, szName, charsmax(szName));

  65.     client_print(0, print_chat, "%s выбрал пункт %d", szName, item);

  66.  

  67.     return PLUGIN_HANDLED

  68. }

  69.  

  70. public EndVote()

  71. {

  72.      // Если первая опция набрала больше голосов, чем вторая

  73.     if (g_Votes[0] > g_Votes[1])

  74.         client_print(0, print_chat, "First option recieved most votes (%d)", g_Votes[0])

  75.     // Иначе если вторая опция набрала больше голосов, чем первая

  76.     else if (g_Votes[1] > g_Votes[0])

  77.         client_print(0, print_chat, "Second option recieved most votes (%d)", g_Votes[1])

  78.     // Иначе равное кол-во голосов

  79.     else

  80.         client_print(0, print_chat, "The vote tied at %d votes each.", g_Votes[0])

  81.  

  82.     menu_destroy(g_VoteMenu)

  83.  

  84.     // Сбрасываем информацию о том, что игроки голосуют

  85.     g_Voting = 0

  86. }
[/pawn]

Будет показывать кто что выбрал, спасибо subb98 :thumbs_up


Это для меня код?
Аватара пользователя
ttodonok
 
Сообщения: 4
Зарегистрирован: 06 сен 2014, 14:17
Благодарил (а): 0 раз.
Поблагодарили: 0 раз.
Опыт программирования: Около 6 месяцев
Языки программирования: Counter-Strike 1.6

Re: Новая система меню AMXX

Сообщение Subb98 » 06 сен 2014, 16:04

ttodonok писал(а):А как мне им написать может есть скайп лил ссылка на их инфу?

Вы должны зарегистрироваться, чтобы видеть ссылки.
«Очень хорошо. Лучше вы, чем я» © Donald J. Trump
Аватара пользователя
Subb98
Модератор
 
Сообщения: 4825
Зарегистрирован: 24 мар 2011, 19:42
Откуда: г. Пермь
Благодарил (а): 1272 раз.
Поблагодарили: 2184 раз.
Опыт программирования: Больше трех лет
Языки программирования: Pawn, PHP

Re: Новая система меню AMXX

Сообщение Dmitry Beast » 07 сен 2014, 19:27

ttodonok писал(а):Это для меня код?

нет, для тех, кому он будет нужен.
Аватара пользователя
Dmitry Beast
 
Сообщения: 1533
Зарегистрирован: 24 дек 2010, 10:35
Откуда: Челябинск
Благодарил (а): 431 раз.
Поблагодарили: 206 раз.
Опыт программирования: Больше трех лет
Языки программирования: All Languages

Пред.След.

Вернуться в Статьи / фрагменты кода

Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 1